From: hz225wu@unidui.uni-duisburg.de (Micaela Pantke)
Subject: Update of the Old Futhark Rune Font for LaTeX
Date: 3 May 1993 09:56:10 +0200

Hi there - Stayka is here!                                1993/05/03

My apologies for sending this stuff again, but I was told by a friend
who successfully built the Klingon alphabet for LaTeX yesterday (as far
as I know he will post it to the net as soon as it's completely ready -
there are some minor adjustments to make...) how I could solve the
problem with the missing blank space in the font.  Furthermore I
corrected the spacing between the letters, they should look better now. 
Unfortunately at the moment I have no tool to make a shar archive of the
files, but I hope you will forgive me... 

BTW, I compiled the runes with the following command. As example I use
the 10pt version of the Futhark font for hp-Laser-/Deskjet (300dpi).
I run Metafont under SCO-Unix, but I'd say it shouldn't be too different
to use the DOS/Mac/Amiga/Atari/??? versions of Metafont. 

mf "\mode:= CanonCX;" "\mag:= 1;" \input futhol10

This will build the gf-file.  To get the pk-file you have to invoke the
program gftopk, and afterwards copy tfm and pk files into the
directories where they belong.

And now again here's the Metafont source for the Older Futhark alphabet
with corrected spacing between the letters.  They are as good as Shavana
and I managed to design them.  I include the parameter files and the
files to compile 10pt, 20pt, 30pt, 40pt and 50pt runes, which should
cover almost every case. 

This font should be used with LaTeX and the old font selection scheme,
as I haven't created a font family and so on for it yet.  Who wants to
use AmS-LaTeX or the new font selection scheme has to put a little more
work in it. 

I didn't encounter any problems compiling this font with Metafont (with 
plain bases, not the computer modern ones), and I hope you don't either.  
Enjoy! 

The first file is the parameter file which I called   futhold.mf

------------------------------ CUT HERE -------------------------------
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%
%  futhold.mf
%
%  Das \"Altere Futhark (The Older Futhark) 
%  Parameter File (1993/05/02)
%
%  Design by Micaela "Stayka" Pantke + Sigrid "Shavana" Juckel
%
%  Email:     hz225wu@unidui.uni-duisburg.de (Micaela Pantke)
%  Snailmail: Micaela Pantke
%             Westhoffstrasse 111
%             46149 Oberhausen
%             Germany
%
%  You're free to use or copy this file as long as you leave this 
%  header intact and don't change the contents.
%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

mode_setup;                 % switches into Metafont mode

ho#:=o#;                    % horizontal overshoot
leftstemloc#:=2.5u#+s#;     % position of left bottom lines
py#:=.9px#;                 % vertical thickness of the pen

define_pixels(s,u);
define_blacker_pixels(px,py);
pickup pencircle xscaled px yscaled py;
runen_pen:=savepen;
define_good_x_pixels(leftstemloc);
define_corrected_pixels(o);  % turns overshoot correction on
define_horizontal_corrected_pixels(ho);

def beginrunenchar(expr code, unit_width) =
 beginchar(code,unit_width*u#+2s#,ht#,0);
 pickup runen_pen enddef;

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%
%  There they are: the runes
%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

beginrunenchar("F",20);
x1=x2=x3=x6=leftstemloc; x4=x5=w-s; 
bot y1=-o; y2=.4h; y3=.7h; y4=.6h; y5=.9h; top y6= h;
draw z1--z6;
draw z3--z5;
draw z2--z4;
labels(1,2,3,4,5); 
endchar;

beginrunenchar("U",30);
x1=x2=leftstemloc; x3=x4=w-s; 
bot y1=bot y4=-o; y3=.6h; top y2=h; 
draw z1--z2--z3--z4; 
labels(1,2,3,4); 
endchar;

beginrunenchar("X",20);                  % This should be a "TH"
x1=x2=x3=x4=leftstemloc; x5=w-s; 
bot y1=-o; y2=.25h; y5=.5h; y3=.75h; top y4=h;
draw z1--z4;
draw z2--z5--z3;
labels(1,2,3,4,5); 
endchar;

beginrunenchar("A",20); 
x1=x2=x3=leftstemloc; x4=x5=w-s; 
bot y1=-o; y2=.7h; y4=.5h; y5=.8h; top y3=h;
draw z1--z3--z5;
draw z2--z4;
labels(1,2,3,4,5); 
endchar;

beginrunenchar("R",20); 
x1=x2=x3=leftstemloc; x4=x5=w-s; 
bot y1=bot y4=-o; y2=.4h; y5=.7h; top y3=h;
draw z1--z3--z5--z2--z4;
labels(1,2,3,4,5); 
endchar;

beginrunenchar("K",20); 
x2=leftstemloc; x1=x3=w-s; 
y1=.4h; y2=.7h; top y3=h;
draw z1--z2--z3;
labels(1,2,3); 
endchar;

beginrunenchar("G",30); 
x1=x2=leftstemloc; x3=x4=w-s; 
bot y1=bot y3=-o; top y2=top y4=h;
draw z1--z4;
draw z2--z3;
labels(1,2,3,4); 
endchar;

beginrunenchar("W",20); 
x1=x2=x3=leftstemloc; x4=w-s; 
bot y1=-o; y2=.4h; y4=.7h; top y3=h;
draw z1--z3--z4--z2;
labels(1,2,3,4); 
endchar;

beginrunenchar("H",30); 
x1=x2=x3=leftstemloc; x4=x5=x6=w-s; 
bot y1=bot y4=-o; y2=.65h; y5=.35h; top y3=top y6=h;
draw z1--z3;
draw z4--z6;
draw z2--z5;
labels(1,2,3,4,5,6); 
endchar;

beginrunenchar("N",20); 
x1=leftstemloc; x2=x3=.5(w+s); x4=w-s; 
bot y2=-o; y1=.6h; y4=.4h; top y3=h;
draw z1--z4;
draw z2--z3;
labels(1,2,3,4); 
endchar;

beginrunenchar("I",10); 
x1=x2=leftstemloc; 
bot y1=-o; top y2=h;
draw z1--z2;
labels(1,2); 
endchar;

beginrunenchar("J",30); 
x1=leftstemloc; x2=.3w; x3=x4=.5(w+s); x5=.7w; x6=w-s; 
bot y5=-o; y1=.3h; y3=.4h; y4=.6h; y6=.7h; top y2=h;
draw z5--z1--z4;
draw z3--z6--z2;
labels(1,2,3,4,5,6); 
endchar;

beginrunenchar("Y",30);       % This should be an "EI" 
x1=leftstemloc; x2=x3=.5(w+s); x4=w-s; 
bot y2=-o; y1=.3h; y4=.7h; top y3=h;
draw z1--z2--z3--z4;
labels(1,2,3,4); 
endchar;

beginrunenchar("P",30); 
x1=x2=leftstemloc; x3=x4=.5(w+s); x5=x6=w-s; 
bot y1=bot y5=-o; y3=.3h; y4=.7h; top y2=top y6=h;
draw z5--z3--z1--z2--z4--z6;
labels(1,2,3,4,5,6); 
endchar;

beginrunenchar("Z",30); 
x1=leftstemloc; x2=x3=x4=.5(w+s); x5=w-s; 
bot y2=-o; y3=.6h; top y1=top y4=top y5=h;
draw z2--z4;
draw z1--z3--z5;
labels(1,2,3,4,5); 
endchar;

beginrunenchar("S",20); 
x1=x2=leftstemloc; x3=x4=w-s; 
bot y1=-o; y3=.3h; y2=.7h; top y4=h;
draw z1--z3--z2--z4;
labels(1,2,3,4); 
endchar;

beginrunenchar("T",30); 
x1=leftstemloc; x2=x3=.5(w+s); x4=w-s; 
bot y2=-o; y1=y4=.7h; top y3=h;
draw z2--z3;
draw z1--z3--z4;
labels(1,2,3,4); 
endchar;

beginrunenchar("B",20); 
x1=x2=x3=leftstemloc; x4=x5=w-s; 
bot y1=-o; y4=.3h; y2=.5h; y5=.7h; top y3=h;
draw z1--z3--z5--z2--z4--z1;
labels(1,2,3,4,5); 
endchar;

beginrunenchar("E",30); 
x1=x2=leftstemloc; x3=.5(w+s); x4=x5=w-s; 
bot y1=bot y5=-o; y3=.7h; top y2=top y4=h;
draw z1--z2--z3--z4--z5;
labels(1,2,3,4,5); 
endchar;

beginrunenchar("M",30); 
x1=x2=x3=leftstemloc; x4=x5=x6=w-s; 
bot y1=bot y4=-o; y2=y5=.4h; top y6=top y3=h;
draw z1--z3--z5;
draw z2--z6--z4;
labels(1,2,3,4,5,6); 
endchar;

beginrunenchar("L",20); 
x1=x2=leftstemloc; x3=w-s; 
bot y1=-o; y3=.6h; top y2=h;
draw z1--z2--z3;
labels(1,2,3); 
endchar;

beginrunenchar("Q",30);                  % And this should be an "ING"
x1=leftstemloc; x2=x3=.5(w+s); x4=w-s; 
y2=.4h; y1=y4=.7h; top y3=h;
draw z1--z3--z4--z2--z1;
labels(1,2,3,4); 
endchar;

beginrunenchar("D",30); 
x1=x2=leftstemloc; x3=x4=w-s; 
bot y1=bot y3=-o; top y2=top y4=h;
draw z1--z2--z3--z4--z1;
labels(1,2,3,4); 
endchar;

beginrunenchar("O",30);  
x1=x2=leftstemloc; x3=.5(w+s); x4=x5=w-s; 
bot y1= bot y4=-o; y2=y5=.7h; top y3=h;
draw z1--z5--z3--z2--z4;
labels(1,2,3,4,5); 
endchar;

beginrunenchar(":",10); 
x1=x2=x3=x4=leftstemloc; 
y1=.2h; y2=.35h; y3=.65h; y4=.8h;
draw z1--z2;
draw z3--z4;
labels(1,2,3,4); 
endchar;

font_coding_scheme:="FUXARKGWHNIJYPZSTBEMLQDO: only";

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%
%  End of File
% 
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
------------------------------ CUT HERE -------------------------------


The next file is the 10pt Metafont file   futhol10.mf :

------------------------------ CUT HERE -------------------------------
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%
%  futhol10.mf
%
%  Das \"Altere Futhark (The Older Futhark)
%  10pt version (1993/05/02)
%
%  Design by Micaela "Stayka" Pantke + Sigrid "Shavana" Juckel
%
%  Email:     hz225wu@unidui.uni-duisburg.de (Micaela Pantke)
%  Snailmail: Micaela Pantke
%             Westhoffstrasse 111
%             46149 Oberhausen
%             Germany
%
%  You're free to use or copy this file as long as you leave this 
%  header intact and don't change the contents.
%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

font_identifier:="futhold"; 
font_size 10pt#;           % design size
ht#:=10pt#;                % height of the letters
u#:=.2pt#;                 % unit width
s#:=.9pt#;                 % width correction right + left
o#:=1/20pt#;               % overshoot
px#:=.7pt#;                % horizontal thickness of the pen
font_normal_space:=7pt#;   % width of blank space
font_normal_shrink:=.9pt#; % width correction for blank space 
font_x_height:=5pt#;       % height of one "ex"
input futhold              % call parameter file 
end                        % and end!

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%
%  End of File
% 
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
------------------------------ CUT HERE -------------------------------


The next file is the 20pt Metafont file   futhol20.mf :

------------------------------ CUT HERE -------------------------------
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%
%  futhol20.mf
%
%  Das \"Altere Futhark (The Older Futhark) 
%  20pt version (1993/05/02)
%
%  Design by Micaela "Stayka" Pantke + Sigrid "Shavana" Juckel
%
%  Email:     hz225wu@unidui.uni-duisburg.de (Micaela Pantke)
%  Snailmail: Micaela Pantke
%             Westhoffstrasse 111
%             46149 Oberhausen
%             Germany
%
%  You're free to use or copy this file as long as you leave this 
%  header intact and don't change the contents.
%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

font_identifier:="futhold"; 
font_size 20pt#;            % design size
ht#:=20pt#;                 % height of the letters
u#:=.4pt#;                  % unit width
s#:=1.1pt#;                 % width correction right + left
o#:=1/10pt#;                % overshoot
px#:=1pt#;                  % horizontal thickness of the pen
font_normal_space:=14pt#;   % width of blank space
font_normal_shrink:=1.1pt#; % width correction for blank space 
font_x_height:=10pt#;       % height of one "ex"
input futhold               % call parameter file 
end                         % and end!

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%
%  End of File
% 
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
------------------------------ CUT HERE -------------------------------


The next file is the 30pt Metafont file   futhol30.mf :

------------------------------ CUT HERE -------------------------------
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%
%  futhol30.mf
%
%  Das \"Altere Futhark (The Older Futhark) 
%  30pt version (1993/05/02)
%
%  Design by Micaela "Stayka" Pantke + Sigrid "Shavana" Juckel
%
%  Email:     hz225wu@unidui.uni-duisburg.de (Micaela Pantke)
%  Snailmail: Micaela Pantke
%             Westhoffstrasse 111
%             46149 Oberhausen
%             Germany
%
%  You're free to use or copy this file as long as you leave this 
%  header intact and don't change the contents.
%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

font_identifier:="futhold"; 
font_size 30pt#;            % design size
ht#:=30pt#;                 % height of the letters
u#:=.6pt#;                  % unit width
s#:=1.3pt#;                 % width correction right + left
o#:=1/7pt#;                 % overshoot
px#:=1.5pt#;                % horizontal thickness of the pen
font_normal_space:=21pt#;   % width of blank space
font_normal_shrink:=1.3pt#; % width correction for blank space 
font_x_height:=15pt#;       % height of one "ex"
input futhold               % call parameter file 
end                         % and end!

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%
%  End of File
% 
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
------------------------------ CUT HERE -------------------------------


The next file is the 40pt Metafont file   futhol40.mf :

------------------------------ CUT HERE -------------------------------
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%
%  futhol40.mf
%
%  Das \"Altere Futhark (The Older Futhark)
%  40pt version (1993/05/02)
%
%  Design by Micaela "Stayka" Pantke + Sigrid "Shavana" Juckel
%
%  Email:     hz225wu@unidui.uni-duisburg.de (Micaela Pantke)
%  Snailmail: Micaela Pantke
%             Westhoffstrasse 111
%             46149 Oberhausen
%             Germany
%
%  You're free to use or copy this file as long as you leave this 
%  header intact and don't change the contents.
%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

font_identifier:="futhold"; 
font_size 40pt#;            % design size
ht#:=40pt#;                 % height of the letters
u#:=.8pt#;                  % unit width
s#:=1.7pt#;                 % width correction right + left
o#:=1/5pt#;                 % overshoot
px#:=2pt#;                  % horizontal thickness of the pen
font_normal_space:=28pt#;   % width of blank space
font_normal_shrink:=1.7pt#; % width correction for blank space 
font_x_height:=20pt#;       % height of one "ex"
input futhold               % call parameter file 
end                         % and end!

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%
%  End of File
% 
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
------------------------------ CUT HERE -------------------------------


The next file is the 50pt Metafont file   futhol50.mf :

------------------------------ CUT HERE -------------------------------
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%
%  futhol50.mf
%
%  Das \"Altere Futhark (The Older Futhark) 
%  50pt version (1993/05/02)
%
%  Design by Micaela "Stayka" Pantke + Sigrid "Shavana" Juckel
%
%  Email:     hz225wu@unidui.uni-duisburg.de (Micaela Pantke)
%  Snailmail: Micaela Pantke
%             Westhoffstrasse 111
%             46149 Oberhausen
%             Germany
%
%  You're free to use or copy this file as long as you leave this 
%  header intact and don't change the contents.
%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

font_identifier:="futhold"; 
font_size 50pt#;          % design size
ht#:=50pt#;               % height of the letters
u#:=1pt#;                 % unit width
s#:=3pt#;                 % width correction right + left
o#:=1/2pt#;               % overshoot
px#:=4pt#;                % horizontal thickness of the pen
font_normal_space:=35pt#; % width of blank space
font_normal_shrink:=3pt#; % width correction for blank space 
font_x_height:=25pt#;     % height of one "ex"
input futhold             % call parameter file 
end                       % and end!

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%
%  End of File
% 
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
------------------------------ CUT HERE -------------------------------

This one is a test file you can use when you have successfully managed
to compile the font: futhold.tex

------------------------------ CUT HERE -------------------------------
\documentstyle{article}
%
%  File: futhold.tex
%  Date: 1993/05/02
%
\parindent0pt
\newfont{\futharknormal}{futhol10}
\newfont{\futharklarge}{futhol20}
\newfont{\futharklarger}{futhol30}
\newfont{\futharkhuge}{futhol40}
\newfont{\futharkmonstrous}{futhol50}
\begin{document}

\begin{tabular}{|c|c|c|}
\hline
\multicolumn{3}{|c|}{\large\bf{}The Older Futhark, 
10pt\rule[-0.5ex]{0pt}{3ex}}\\
\hline
\hline
Letter to type in & 'Real Letter' & Rune \\
\hline
\rule{0pt}{3ex} F & F & {\futharknormal F } \\
U & U & {\futharknormal U } \\
X & TH & {\futharknormal X } \\
A & A & {\futharknormal A } \\
R & R & {\futharknormal R } \\
K & K & {\futharknormal K } \\
G & G & {\futharknormal G } \\
W & W & {\futharknormal W } \\
H & H & {\futharknormal H } \\
N & N & {\futharknormal N } \\
I & I & {\futharknormal I } \\
J & J & {\futharknormal J } \\
Y & EI & {\futharknormal Y } \\
P & P & {\futharknormal P } \\
Z & Z & {\futharknormal T } \\
S & S & {\futharknormal S } \\
T & T & {\futharknormal T } \\
B & B & {\futharknormal B } \\
E & E & {\futharknormal E } \\
M & M & {\futharknormal M } \\
L & L & {\futharknormal L } \\
Q & ING & {\futharknormal Q } \\
D & D & {\futharknormal D } \\
O & O & {\futharknormal O } \\
: & : & {\futharknormal : } \\
\hline
\end{tabular}

\pagebreak
{\bf FUTHARK, 10pt}\\[1ex]
{\futharknormal FUXARK}

\vspace{3ex}
{\bf FUTHARK, 20pt}\\[1ex]
{\futharklarge FUXARK}

\vspace{3ex}
{\bf FUTHARK, 30pt}\\[1ex]
{\futharklarger FUXARK}

\vspace{3ex}
{\bf FUTHARK, 40pt}\\[1ex]
{\futharkhuge  FUXARK}

\vspace{3ex}
{\bf FUTHARK, 50pt}\\[1ex]
{\futharkmonstrous  FUXARK}

\end{document}
------------------------------ CUT HERE -------------------------------


Walk in the Light!
                    Stayka deyAvemta

-------------------------------------------------------------------------
Email: hz225wu@unidui.uni-duisburg.de  |  We live in a universe of magic!
-------------------------------------------------------------------------